расчленение блоков в блоках в блоках ...

(defun test (/ adoc *error* fun_explode err_lst)
  (defun *error* (msg)
    (vla-endundomark adoc)
    (princ msg)
    (princ)
    ) ;_ end of defun
  (defun fun_explode (ent / lst)
    (cond
      ((= (vla-get-objectname ent) "AcDbBlockReference")
       (if (not (vl-catch-all-error-p
                  (vl-catch-all-apply
                    '(lambda ()
                       (setq lst (vlax-safearray->list
                                   (vlax-variant-value (vla-explode ent))
                                   ) ;_ end of vlax-safearray->list
                             ) ;_ end of setq
                       ) ;_ end of lambda
                    ) ;_ end of vl-catch-all-apply
                  ) ;_ end of vl-catch-all-error-p
                ) ;_ end of not
         (progn
           (foreach item lst
             (fun_explode item)
             ) ;_ end of foreach
           (vla-erase ent)
           ) ;_ end of progn
         ) ;_ end of if
       )
      ((and (= (vla-get-objectname ent) "AcDbBlockTableRecord")
            (equal (vla-get-islayout ent) :vlax-false)
            (equal (vla-get-isxref ent) :vlax-false)
            ) ;_ end of and
       (vlax-for sub ent
         (fun_explode sub)
         ) ;_ end of vlax-for
       )
      ((and (vlax-property-available-p ent 'islayout)
            (equal (vla-get-islayout ent) :vlax-true)
            ) ;_ end of and
       (vlax-for sub ent
         (fun_explode sub)
         ) ;_ end of vlax-for
       )
      ) ;_ end of cond
    ) ;_ end of defun
  (vl-load-com)
  (vla-startundomark
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    ) ;_ end of vla-startundomark
  (vlax-for blk_def (vla-get-blocks adoc)
    (fun_explode blk_def)
    ) ;_ end of vlax-for
  (vlax-for blk_def (vla-get-blocks adoc)
    (vl-catch-all-apply '(lambda () (vla-erase blk_def)))
    ) ;_ end of vlax-for
  (vla-endundomark adoc)
  (princ)
  ) ;_ end of defun