Как смастерить пересечение линий

(defun C:LINECROSS ()
 (while
  (progn
   (setq e0 nil d0 nil)
   (if (setq e0 (car (entsel "\nSelect LINE: "))) ;выбор Отрезка
    (progn
     (prompt "\nThis is NOT a LINE.")
     (not (= (cdr (assoc 0 (setq d0 (entget e0)))) "LINE"))))))
 (if e0
  (progn
   (setq sp0 (cdr (assoc 10 d0)) ep0 (cdr (assoc 11 d0))) ;начальная и конечная точки Отрезка
   (grdraw sp0 ep0 1 1) ;выделение Отрезка
   (prompt "\nSelect crossing LINES...")
   (setq ss (ssget (list '(0 . "LINE")))) ;выбор пересекающих отрезков
   (if ss ;отрезки выбраны
    (progn
     (setq dist_list ()) ;список_расстояний в формате ((длина координаты_точки_пересечения)...)
     (setq i 0)
     (repeat (sslength ss)
      (setq d (entget (setq e (ssname ss i)))) ;сведения об очередном отрезке
      (setq sp (cdr (assoc 10 d)) ep (cdr (assoc 11 d))) ;начальная и конечная точки очередного отрезка
      (if (setq cp (inters sp0 ep0 sp ep T)) ;точка_пересечения есть
       (if (not (apply 'or (mapcar '(lambda (_p) (equal (distance cp _p) 0.0 1e-13)) (list sp0 ep0 sp ep)))) ;очередной отрезок не примыкает и не проходит через концы Отрезка
        (setq dist_list (cons (cons (distance sp0 cp) cp) dist_list)))) ; пополнение списка_расстояний
      (setq i (1+ i)))
     (setq radius
      (if
       (setq
        new_radius
        (progn
         (initget (+ (if (> radius 0.0) 0 1) 2 4))
         (getreal (strcat "\nRadius" (if (> radius 0.0) (strcat " <" (rtos radius) ">") "") ": ")))) ;радиус дуги
       new_radius
       radius))
     (setq lwpline_list
      (mapcar 'cons
       (list 0 100 67 410 8 100 90 70 43 38 39)
       (list "LWPOLYLINE" "AcDbEntity" (cdr (assoc 67 d0)) (cdr (assoc 410 d0)) (cdr (assoc 8 d0)) "AcDbPolyline" 0 0 0.0 0.0 0.0))) ;"заголовок" полилинии
     (setq vertex_count 0) ;количество вершин
     (setq
      lwpline_list
      (append lwpline_list
       (mapcar 'cons
        (list 10 40 41 42)
        (list sp0 0.0 0.0 0.0))) ;первая вершина полилинии
      vertex_count (1+ vertex_count))
     (while dist_list ;точки пересечения не кончились
      (setq prox_list (assoc (apply 'min (mapcar 'car dist_list)) dist_list)) ;обнаружение очередной ближайшей к начальной точке Отрезка точки_пересечения
      (setq cp (cdr prox_list)) ;координаты точки_пересечения
      (setq
       lwpline_list
       (append lwpline_list
        (mapcar 'cons
         (list 10 40 41 42)
         (list (polar cp (angle cp sp0) radius) 0.0 0.0 1.0))) ;сегмент от точки_пересечения в сторону начальной точки (дуговой)
       vertex_count (1+ vertex_count))
      (setq
       lwpline_list
       (append lwpline_list
        (mapcar 'cons
         (list 10 40 41 42)
         (list (polar cp (angle cp ep0) radius) 0.0 0.0 0.0))) ;сегмент от точки_пересечения в сторону конечной точки (линейный)
       vertex_count (1+ vertex_count))
      (setq dist_list (apply 'append (mapcar '(lambda (_x) (if _x (list _x))) (subst nil prox_list dist_list))))) ;сокращение списка_расстояний
     (setq lwpline_list
      (append lwpline_list
       (mapcar 'cons
        (list 10 40 41 42)
        (list ep0 0.0 0.0 0.0))) ;последняя вершина полилинии
      vertex_count (1+ vertex_count))
     (setq
      lwpline_list
      (append lwpline_list
       (mapcar 'cons
        (list 210)
        (list '(0 0 1))))) ;нормаль
     (setq lwpline_list (subst (cons 90 vertex_count) (assoc 90 lwpline_list) lwpline_list)) ;замена количества вершин
     (entmake lwpline_list) ;создание полилинии
     (entdel e0))) ;удаление Отрезка
   (redraw) ;стирание фантомного отрезка
  )
 )
 (prin1)
)