Где сохраняется Поворот Текста??? (Страница 1 из 2)

;;;Ф-ция возвращает угол поворота текста в виде списка
;;;(угол_в_радианах угол_в_градусах)
(defun povorot_texta ( / ug)
(if (zerop (cdr (assoc 40 (tblsearch "STYLE" (getvar "TEXTSTYLE")))))
  (COMMAND "_TEXT" "0,0" 1.0 "" "TEST") ;_ нулевая высота текста Будет запрос высоты
  (COMMAND "_TEXT" "0,0" "" "TEST")     ;_ фиксированнная высота Запроса не будет
  );_end of if
 (setq ug (cdr(assoc 50 (entget(entlast)))))
 (entdel(entlast))
 (list ug (/ (* ug 180.0) pi)))
;;;Пример
(defun c:TEST ( / ug)
  (setq ug (povorot_texta))
  (princ "\nТекущий угол поворота: ")
  (princ (car ug))(princ " радиан или ")
  (princ (cadr ug))(princ " градусов")
  (princ)
  )

(defun ru-text-draw (txt pnt height rotation justification)
  (ru-var-clear-osnap)
   (if (= (cdr (assoc 40 (tblsearch "STYLE" (getvar "TEXTSTYLE"))))
      0.0
       ) ;_ end of =
     (progn
     ;; нулевая высота текста
       (if justification
     (vl-cmdf "_.TEXT" "_J" justification pnt height rotation txt)
     (vl-cmdf "_.TEXT" pnt height rotation txt)
       ) ;_ end of if
     ) ;_ end of progn
     (progn
       ;; фиксированнная высота
       (if justification
     (vl-cmdf "_.TEXT" "_J" justification pnt rotation txt)
     (vl-cmdf "_.TEXT" pnt rotation txt)
       ) ;_ end of if
     ) ;_ end of progn
   ) ;_ end of if
  (ru-lw-set-for-ent (entlast) (ru-lw-calc-for-text height))
  (ru-var-restore-osnap)
  (entlast)
)

(defun ru-text-add (txt pnt height rotation justification / obj)
  ;|
justification:
 0 acAlignmentLeft
 1 acAlignmentCenter
 2 acAlignmentRight
 3 acAlignmentAligned
 4 acAlignmentMiddle
 5 acAlignmentFit
 6 acAlignmentTopLeft
 7 acAlignmentTopCenter
 8 acAlignmentTopRight
 9 acAlignmentMiddleLeft
10 acAlignmentMiddleCenter
11 acAlignmentMiddleRight
12 acAlignmentBottomLeft
13 acAlignmentBottomCenter
14 acAlignmentBottomRight
|;
  (if (null justification)
    (setq justification acalignmentleft)
  ) ;_ end of if
  (ru-error-catch
    (function
      (lambda ()
        (setq
          obj
           (vla-addtext
             (ru-obj-active-space)
             txt
             (if
               (or (= justification acalignmentaligned)
                   (= justification acalignmentfit)
               ) ;_ end of or
                (vlax-3d-point (car pnt))
                (vlax-3d-point pnt)
             ) ;_ end of if
             height
           ) ;_ end of vla-AddText
        ) ;_ end of setq
        (ru-lw-set-for-obj obj (ru-lw-calc-for-text height))
        (cond
          ((= justification acalignmentleft)
           (vla-put-rotation obj rotation)
          )
          ((or (= justification acalignmentaligned)
               (= justification acalignmentfit)
           ) ;_ end of or
           (vla-put-alignment obj justification)
           (vla-put-textalignmentpoint
             obj
             (vlax-3d-point (cadr pnt))
           ) ;_ end of vla-put-textalignmentpoint
          )
          (t
           (vla-put-alignment obj justification)
           (vla-put-textalignmentpoint obj (vlax-3d-point pnt))
           (vla-put-rotation obj rotation)
          )
        ) ;_ end of cond
        (vla-update obj)
        obj
      ) ;_ end of lambda
    ) ;_ end of cond
    (function (lambda (x) (princ (strcat "\nОШИБКА RU-TEXT-ADD: " x)) nil))
  ) ;_ end of ru-error-catch
) ;_ end of defun

(defun ru-text-entmake (txt pnt height rotation justification / ent_list)
  (setq    ent_list (list    '(0 . "TEXT")
         '(100 . "AcDbEntity")
         '(100 . "AcDbText")
         (list 10 (car pnt) (cadr pnt) 0.0)
         (cons 1 txt)
         (cons 40 height)
         ;;(cons 7 "RU_CAD")
         (if justification
           (cond
             ((= justification "C")
              '(72 . 1)
             )
             ((= justification "R")
              '(72 . 2)
             )
             ((= justification "A")
              '(72 . 3)
             )
             ((= justification "M")
              '(72 . 4)
             )
             ((= justification "F")
              '(72 . 5)
             )
             (t
              '(72 . 0)
             )
           ) ;_ end of cond
           '(72 . 0)
         ) ;_ end of if
         (cons 50 rotation)
         (list 11 (car pnt) (cadr pnt) 0.0)
       ) ;_ end of list
   ) ;_ end of setq
   (setq ent_list (entmake ent_list))
   (ru-lw-set-for-ent (entlast) (ru-lw-calc-for-text height))
  (entlast)
)