генератор случайных чисел ОЧЕНЬ НУЖЕН

;;; ************************************************************************
;;; * Библиотека DWGruLispLib Copyright ©2007  DWGru Programmers Group
;;; *
;;; *http://dwg.ru/f/showthread.php?p=218772
;;; *
;;; * _dwgru-random
;;; *
;;;  На основе vk_RandNum
;;;  https://www.caduser.ru/forum/topic32763.html
;;; *
;;; *
;;; * 07/12/2007 Версия 0001.  Редакция Владимир Азарко (VVA)
;;; ************************************************************************
(defun _dwgru-random (/ modulus multiplier increment)
;;; Генерирует случайное вещественное число в диапазоне от 0 до 1
;;; Используется глобальная переменная *DWGRU_SEED*
  (if (not *DWGRU_SEED*)
    (setq *DWGRU_SEED* (getvar "DATE"))
  )
  (setq  modulus     65536
  multiplier 25173
  increment  13849
  *DWGRU_SEED*     (rem (+ (* multiplier *DWGRU_SEED*) increment) modulus))
  (/ *DWGRU_SEED* modulus)
)
;;; ************************************************************************
;;; * Библиотека DWGruLispLib Copyright ©2007  DWGru Programmers Group
;;; *
;;; * dwgru-random-range
;;; *
;;; *http://dwg.ru/f/showthread.php?p=218772
;;; *
;;; * 07/12/2007 Версия 0001.  Редакция Владимир Азарко (VVA)
;;; ************************************************************************
(defun dwgru-random-range (Minnum Maxnum )
;;; Генерирует случайное число из указанного диапазона целых чисел
;;; Использует функцию библиотеки
    ;;;                 _dwgru-random
    ;;; Параметры:
    ;;; Minnum - минимальное целое число
    ;;; Maxnum - максимальное целое число
    ;;; Возврат:
    ;;;   целое число из указанного диапазона
    ;;; Пример:
  ;|
  (DWGRU-NUM-RANDOM-RANGE 1 15) ;_Результат 3
  (DWGRU-NUM-RANDOM-RANGE 1 15) ;_Результат 10
  |;
;(- Maxnum (atoi (rtos (* (- Maxnum Minnum) (_dwgru-num-random)) 2 0))) ;_Comment VVA 07.12.2007 Было так
(- Maxnum (fix (* (- Maxnum Minnum) (_dwgru-random)))) ;_Add VVA 07.12.2007 Так наверное быстрее
)
;;Text Random number
;;https://www.caduser.ru/forum/topic37867.html
(defun c:TR (/ From To SS Ent Num i)
(initget 1)
(setq From (getint "Укажите диапазон. Минимум: "))
(while
  (progn
    (initget 1)
    (not (> (setq To (getint "Укажите диапазон. Максимум: ")) From))
    )
)
(and
(setq SS (ssget "_:L" '((0 . "*TEXT"))))
(repeat (setq i (sslength SS)) ;_ end setq
  (setq Ent (entget (ssname SS (setq i (1- i)))))
  (setq Num (dwgru-random-range From To))
  (entmod (subst (cons 1 (if (<= Num 0)(itoa Num)
                           (strcat "+" (itoa Num))))
                 (assoc 1 Ent)
                 Ent
                 )
          )
 ) ;_ end repeat
)
(princ)
)