LISP. Общее. Загрузка файла. Вызовы функций (Страница 2 из 3)

;загрузка библиотеки лиспов
(mapcar  'load
  (z-files-in-directory (getenv "*z_root_dir*") '("*.lsp" "*.fas" "*.vlx") t)
  ) ;_ mapcar

;загрузка библиотеки лиспов с отловом ошибок
(vl-load-com) ;_На всякий случай
(foreach fil (z-files-in-directory (getenv "*z_root_dir*") '("*.lsp" "*.fas" "*.vlx") t)
      (if (vl-catch-all-error-p
      (vl-catch-all-apply '(lambda ()(load fil))))
    (princ (strcat "\nОшибка загрузки файла " fil))
    )
      )

(defun test (/ file)
  (setq file
         (findfile
           "e:\\files\\cadware\\lsp\\db\\insert\\leader\\_kpblc-db-insert-leader.lsp"
           ) ;_ end of findfile
        ) ;_ end of setq
  (load (strcase file) "Файл не найден")
  ) ;_ end of defun

(vl-load-com) ;_На всякий случай
;|=======================================================================================
*    функция z-files-in-directory возвращает список файлов находящаяся в заданной
* директории
*    Автор : Зуенко Виталий (ZZZ)
*  Параметры:
*    directory  путь к папке например "D:\\Мои документы\\ZEF\\Lisp"
*    pattern    шаблон например "*.lsp" или список '("*.dwg" "*.dxf")
*    nested    искать в вложенных папках: t (да) или nil (нет)
* Пример вызова:
(z-files-in-directory "D:\\Мои документы\\ZEF\\Lisp" "*.lsp" t)
(z-files-in-directory "D:\\Мои документы\\ZEF\\Lisp" '("*.lsp" "*.fas") t)
=======================================================================================|;
(defun z-files-in-directory (directory pattern nested /)
  (if (not (listp pattern))
    (setq pattern (list pattern))
    ) ;_ if
  (if nested
    (apply
      'append
      (append
  (mapcar  '(lambda (_pattern)
       (mapcar '(lambda (f) (strcat directory "\\" f))
         (vl-directory-files directory _pattern 1)
         ) ;_ list
       ) ;_ lambda
    pattern
    ) ;_ mapcar
  (mapcar
    '(lambda (d)
       (z-files-in-directory
         (strcat directory "\\" d)
         pattern
         nested
         ) ;_ z-files-in-directory
       ) ;_ lambda
    (vl-remove
      "."
      (vl-remove ".." (vl-directory-files directory nil -1))
      ) ;_ vl-remove
    ) ;_ mapcar
  ) ;_ append
      ) ;_ append
    (apply
      'append
      (mapcar '(lambda (_pattern)
     (mapcar '(lambda (f) (strcat directory "\\" f))
       (vl-directory-files directory _pattern 1)
       ) ;_ list
     ) ;_ lambda
        pattern
        ) ;_ mapcar
      ) ;_ apply
    ) ;_ if
  ) ;_ defun
;(BrowseFolder)
;http://discussion.autodesk.com
(defun BrowseFolder ( / ShlObj Folder FldObj OutVal)
  (vl-load-com)
  (setq
    ShlObj (vla-getInterfaceObject
       (vlax-get-acad-object)
       "Shell.Application"
     )
    Folder (vlax-invoke-method ShlObj 'BrowseForFolder 0 "" 0)
  )
  (vlax-release-object ShlObj)
  (if Folder
    (progn
      (setq
  FldObj (vlax-get-property Folder 'Self)
  OutVal (vlax-get-property FldObj 'Path)
      )
      (vlax-release-object Folder)
      (vlax-release-object FldObj)
      OutVal
    )
  )
)

; Проверка и задание переменной *z_root_dir* путь к папке автозагрузки
(if (or  (not (getenv "*z_root_dir*"))
  (= (getenv "*z_root_dir*") "")
  ) ;_ or
  (setenv "*z_root_dir*" (BrowseFolder))
)
; Обнуление переменной *z_root_dir* для задания нового пути к папке
;(setenv  "*z_root_dir*" "")
;|
;Вместо старого кода
;загрузка библиотеки лиспов
(mapcar  'load
  (z-files-in-directory (getenv "*z_root_dir*") '("*.lsp" "*.fas" "*.vlx") t)
  ) ;_ mapcar
|;
;загрузка библиотеки лиспов и arx модулей с отловом ошибок и запросом директории
(foreach fil (z-files-in-directory
               (getenv "*z_root_dir*")
               '("*.lsp" "*.fas" "*.vlx" "*.arx")
               t
             ) ;_ end of z-files-in-directory
  (if (vl-catch-all-error-p
        (vl-catch-all-apply
          '(lambda ()
             (if (= (strcase (vl-filename-extension fil)) ".ARX")
               (arxload fil)
               (load fil)
             ) ;_ end of if
           ) ;_ end of lambda
        ) ;_ end of vl-catch-all-apply
      ) ;_ end of vl-catch-all-error-p
    (princ (strcat "\nОшибка загрузки файла " fil))
  ) ;_ end of if
) ;_ end of foreach