Тема: LISP. Отрисовка внешнего контура выбранных объектов

Идея зародилась в теме Контур по блоку
В отличие от последнего кода по ссылке строит полилинию для _boundary не на фиксированном расстоянии, а на 1/5 от максимальной длины или ширины габарита выбранных объектов

;https://www.caduser.ru/forum/topic30797.html
;| ! *******************************************************************
;; !                  lib:IsPtInView
;; ! *******************************************************************
;; ! Проверяет находится ли точка в видовом экране
;; ! Auguments: 'pt'  — Точка для анализа в МСК!!!
;; ! Return   : T или nil если 'pt' в видовом экране или нет
;; ! *******************************************************************|;
(defun lib:IsPtInView (pt / VCTR Y_Len SSZ X_Pix Y_Pix X_Len Lc Uc)
(setq pt (trans pt 0 1))
(setq VCTR (getvar "VIEWCTR") Y_Len (getvar "VIEWSIZE")
   SSZ (getvar "SCREENSIZE") X_Pix (car SSZ) Y_Pix (cadr SSZ)
   X_Len (* (/ X_Pix Y_Pix) Y_Len)
   Lc (polar VCTR (dtr 180.0) (* 0.5 X_Len))
   Uc (polar Lc 0.0 X_Len) Lc (polar Lc (dtr 270.0) (* 0.5 Y_Len))
   Uc (polar Uc (dtr 90.0) (* 0.5 Y_Len)))
(if (and (> (car pt) (car Lc))(< (car pt) (car Uc))
   (> (cadr pt) (cadr Lc))(< (cadr pt) (cadr Uc))) T nil))
(defun DTR (a)(* pi (/ a 180.0)))(defun RTD (a)(/ (* a 180.0) pi))
; ! ***********************************************************
;; !                             lib:Zoom2Lst
;; ! **********************************************************
;; ! Function : Zoom границ списка точек
;; ! Arguments: 'vlist' — Список точек в МСК!!!!
;; ! Зуммирует экран, чтобы все точки были видны
;; ! Returns  : t — было зуммирование nil — нет
;; ! **********************************************************
(defun lib:Zoom2Lst( vlist / bl tr Lst OS)
(setq  Lst (lib:pt_extents vlist) bl (car Lst) tr (cadr Lst))
(if (not (and (lib:IsPtInView bl) (lib:IsPtInView tr)))
(progn  (setq OS (getvar "OSMODE"))(setvar "OSMODE" 0)
  (command "_.Zoom" "_Window" (trans bl 0 1)(trans tr 0 1) "_.Zoom" "0.95x")
  (setvar "OSMODE" OS) T) NIL))
;| ! ***************************************************************************
;; !           lib:pt_extents
;; ! ***************************************************************************
;; ! Function : Возвращает границы MIN, MAX X,Y,Z списка точек
;; ! Argument : 'vlist' — Список точек
;; ! Returns  : Список точек (ЛевНижн ПравВерхн)
;; ! ***************************************************************************|;
(defun  lib:pt_extents (vlist / tmp)
(setq tmp (mapcar '(lambda (x) (vl-remove-if 'null x))
 (mapcar '(lambda (what) (mapcar '(lambda (x) (nth what x)) vlist)) '(0 1 2))));_setq
  (list (mapcar '(lambda(x)(apply 'min x)) tmp)(mapcar '(lambda(x)(apply 'max x)) tmp)));_defun
;https://www.caduser.ru/forum/topic30797.html
;External contour of objects
(defun C:ECO ( / *error* blk obj MinPt MaxPt hiden pt pl unnamed_block isRus
          tmp_blk adoc blks lays lay oname sel csp loc sc ec ret DS osm)
(defun *error* (msg)(mapcar '(lambda (x) (vla-put-Visible x :vlax-true)) hiden)
(vla-endundomark adoc)(if (and tmp_blk (not (vlax-erased-p tmp_blk))(vlax-write-enabled-p tmp_blk) )
(vla-Erase tmp_blk))(if osm (setvar "OSMODE" osm))(foreach x loc (vla-put-lock x :vlax-true)))
(vl-load-com)(setvar "CMDECHO" 0)(setq osm (getvar "OSMODE"))
 (if (zerop (getvar "WORLDUCS"))(progn(vl-cmdf "_.UCS" "")(vl-cmdf "_.Plan" "")))
(setq isRus (= (getvar "SysCodePage") "ANSI_1251"))
(setq adoc (vla-get-ActiveDocument (vlax-get-acad-object))
        blks (vla-get-blocks adoc) lays (vla-get-layers adoc))
  (vla-startundomark adoc)(if isRus (princ "\nВыберите объекты для построения контура")(princ "\nSelect objects for making a contour"))
 (if (setq sel (ssget))(progn
    (setq sel (mapcar 'vlax-ename->vla-object(vl-remove-if 'listp (mapcar 'cadr (ssnamex sel)))))
    (setq csp (vla-objectidtoobject adoc (vla-get-ownerid (car sel))))
    (setq unnamed_block (vla-add (vla-get-blocks adoc)(vlax-3d-point '(0. 0. 0.)) "*U"))
    (foreach x sel
      (setq oname (strcase (vla-get-objectname x)) lay  (vla-item lays (vla-get-layer x)))
        (if (= (vla-get-lock lay) :vlax-true)
          (progn (vla-put-lock lay :vlax-false) (setq loc (cons lay loc))))
      (cond ((member oname '("ACDBVIEWPORT" "ACDBATTRIBUTEDEFINITION")) nil)
        ((= oname "ACDBBLOCKREFERENCE")
         (vla-InsertBlock unnamed_block
           (vla-get-insertionpoint x)(vla-get-name x)
           (vla-get-xscalefactor x)(vla-get-yscalefactor x)
           (vla-get-zscalefactor x)(vla-get-rotation x))
         (setq blk (cons x blk)))
        (t (setq obj (cons x obj)))));_foreach
        (setq lay  (vla-item lays (getvar "CLAYER")))
        (if (= (vla-get-lock lay) :vlax-true)(progn (vla-put-lock lay :vlax-false) (setq loc (cons lay loc))))
     (if obj (progn (vla-copyobjects (vla-get-activedocument (vlax-get-acad-object))
              (vlax-make-variant (vlax-safearray-fill
                  (vlax-make-safearray vlax-vbobject (cons 0 (1- (length obj))))
                  obj)) unnamed_block)))
    (setq obj (append obj blk))
    (if obj (progn
          (setq tmp_blk (vla-insertblock csp (vlax-3d-point '(0. 0. 0.))(vla-get-name unnamed_block) 1.0 1.0 1.0 0.0))
          (vla-GetBoundingBox tmp_blk 'MinPt 'MaxPt)  ;_Границы блока
               (setq MinPt (vlax-safearray->list MinPt) MaxPt (vlax-safearray->list MaxPt)
             DS (max (distance MinPt (list (car MinPt)(cadr MaxPt)))
                 (distance MinPt (list (car MaxPt)(cadr MinPt))))
                 DS (* 0.2 DS) ;1/5
             DS (max DS 10) MinPt (mapcar '- MinPt (list DS DS))
                     MaxPt (mapcar '+ MaxPt (list DS DS)))
(lib:Zoom2Lst (list MinPt MaxPt))(setq sset (ssget "_C" MinPt MaxPt))
(if sset (progn (setvar "OSMODE" 0)
      (setq hiden (mapcar 'vlax-ename->vla-object(vl-remove-if 'listp (mapcar 'cadr (ssnamex sset))))
        hiden (vl-remove tmp_blk hiden))
      (mapcar '(lambda(x)(vla-put-Visible x :vlax-false)) hiden)
      (setq pt (mapcar '+ MinPt (list (* 0.5 DS)(* 0.5 DS))))
      (vl-cmdf "_.RECTANG" (trans MinPt 0 1)(trans MaxPt 0 1))
      (setq pl (vlax-ename->vla-object(entlast)))
      (setq sc (1-(vla-get-count csp)))
      (if (VL-CATCH-ALL-ERROR-P (VL-CATCH-ALL-APPLY '(lambda ()
         (vl-cmdf "_-BOUNDARY" (trans pt 0 1) "")
              (while (> (getvar "CMDACTIVE") 0)(command "")))))
      (if isRus (princ "\nНе удалось построить контур")(princ "\nIt was not possible to construct a contour")))
      (setq ec (vla-get-count csp))
        (while (< sc ec)(setq ret (append ret (list (vla-item csp sc))) sc(1+ sc)))
      (setq ret (vl-remove pl ret))
      (mapcar '(lambda (x)(vla-Erase x)(vlax-release-object x))(list pl tmp_blk))(setq pl nil tmp_blk nil)
      (setq ret (mapcar '(lambda ( x / mipt)(vla-GetBoundingBox x 'MiPt nil)  ;_Границы блока
                 (setq MiPt (vlax-safearray->list MiPt))(list MiPt x)) ret))
      (setq ret (vl-sort ret '(lambda (e1 e2)(< (distance MinPt (car e1))(distance MinPt (car e2))))))
      (setq pl (nth 1 ret) ret (vl-remove pl ret))(mapcar 'vla-erase (mapcar 'cadr ret))
      (mapcar '(lambda(x)(vla-put-Visible x :vlax-true)) hiden)
      (foreach x loc (vla-put-lock x :vlax-true))
      (if pl (progn (initget  "Yes No")
      (if (= (getkword (if isRus "\nУдалять объекты? [Yes/No] <No> : " "\nDelete objects? [Yes/No] <No> : ")) "Yes")
         (mapcar '(lambda (x) (if (vlax-write-enabled-p x)(vla-Erase x))) obj)))
    (if isRus (princ "\nНе удалось построить контур")(princ "\nIt was not possible to construct a contour")))))))
     (VL-CATCH-ALL-APPLY '(lambda ()(mapcar 'vlax-release-object
    (list unnamed_block tmp_blk csp blks lays))))));_if not
  (foreach x loc (vla-put-lock x :vlax-true))(setvar "OSMODE" osm)
  (vla-endundomark adoc)(vlax-release-object adoc)(princ))
(if (= (getvar "SysCodePage") "ANSI_1251")(princ "\nНаберите в командной строке ECO")(princ "\nType ECO in command line"))

Re: LISP. Отрисовка внешнего контура выбранных объектов

Пробую, пробую но ни как не получается.
Просмотрел все ссылки, все советы - нет.
Бдьте добры, разжуйте самоучке что, куда и как!

Re: LISP. Отрисовка внешнего контура выбранных объектов

> jonas
Что не получается?
Как сохранить программный код на своем компьютере
Как запустить программу на лиспе, создать свое меню

Re: LISP. Отрисовка внешнего контура выбранных объектов

> VVA
Дак все так и делаю, не в первый раз.
Не понимаю почему по ссылке команда _BC а defun lib:IsPtInView ?

Re: LISP. Отрисовка внешнего контура выбранных объектов

Все, работает.
Не разглядел что команда _ECO.

Re: LISP. Отрисовка внешнего контура выбранных объектов

Программа работает отлично, а цены бы вообще не было если дополнить её следующим образом:
-по созданному контуру строится _wipeout _p;
-Создание блока из выбранного массива элементов и созданного контура командой wipeout (для корректного отображения выбранный массив должен копироваться в созданном блоке поверх созданного wipeout (спасибо к сожалению не помню кому за совет на dwg.ru))
Будет автоматически создаваться хитрый блок, что очень полезно.

Re: LISP. Отрисовка внешнего контура выбранных объектов

Ой какая хорошая программа. спасибо
хорошо бы для многих примитивов за раз контур отрисовывать
а мне бы еще бы хотелось чтоб разнесенные объёкты контурила и строила контур как можно большей площади

Re: LISP. Отрисовка внешнего контура выбранных объектов

Незнайка пишет:

хорошо бы для многих примитивов за раз контур отрисовывать

Так она это и делает

а мне бы еще бы хотелось чтоб разнесенные объёкты контурила и строила контур как можно большей площади

Тогда

_rectang -1e20,-1e20 1e20,1e20

построит почти самый большой контур

Re: LISP. Отрисовка внешнего контура выбранных объектов

> VVA
нет прога удаляет(или не обрисует) разнесенные группы объктов, телько для первой кучки(группы) все получиться
с прямоугольником, что шутка

Re: LISP. Отрисовка внешнего контура выбранных объектов

> Незнайка
Оставляется самый внешний контур, внутренние островки удаляются. Если объекты разнесены, то 1-й контур остается, остальные удаляются. Т.к. нет возможности определить это контур разнесенного объекта или внутренний. Нужно N раз повторить команду для каждой группы.

с прямоугольником, что шутка

И да и нет.
Ты пишешь

и строила контур как можно большей площади

Я так понимаю, что контур как можно большей площади - это прямоугольник с почти максимальными для Автокада координатами.

Re: LISP. Отрисовка внешнего контура выбранных объектов

и строила контур как можно большей площади для выделенных разнесенных групп ,
но я уже понял, что это невозможно
спасибо

Re: LISP. Отрисовка внешнего контура выбранных объектов

Чего-то с текстами ета "ECO" не хочет работать.

Re: LISP. Отрисовка внешнего контура выбранных объектов

т.е. с текстовыми примитивами.

Re: LISP. Отрисовка внешнего контура выбранных объектов

> 12345
Не хочет, потому что с текстами не работает
_boundary

Re: LISP. Отрисовка внешнего контура выбранных объектов

Жалко. У нас тексты обязательно присутствуют.

Re: LISP. Отрисовка внешнего контура выбранных объектов

Придется как обычно корячится вручную, т.е. обводить объекты вручную.

Re: LISP. Отрисовка внешнего контура выбранных объектов

Для > 12345 (2007-04-05 16:29:44)
Макрос для кнопки
Рамка вокруг текста:
^C^C^P(defun C:tmp_Den ()(setq a(entget(car(entsel)))b(cdr(assoc 10 a)))(command "_rectang" (mapcar '- b '(1 1 0))(mapcar '+ b '(1 1 0)(cadr(Textbox a)))"_rotate"(entlast)"" b(angtos(cdr(assoc 50 a)))"'_matchprop"(cdar a)(entlast)"")(setq a nil b a)(princ));tmp_Den

Re: LISP. Отрисовка внешнего контура выбранных объектов

> Сергей
Не пойдет такое.
Нужен общий-групповой контур для нескольких текстовых строк и других нетекстовых примитивов, чтоб делать на основе такого контура WIPEOUT.

Re: LISP. Отрисовка внешнего контура выбранных объектов

> 12345
Построй с помощью макроса вокруг текстов прямоугольники, их ECO возьмет. Но учти, что _boundary строит дуговые сегменты, чего wipeout не приемлет.
Если возможны дуговые сегменты, можно применить
ConvTo2d отсюда http://dwg.ru/dnl/607

Re: LISP. Отрисовка внешнего контура выбранных объектов

> VVA
Спасибо. Буду пробовать.

Re: LISP. Отрисовка внешнего контура выбранных объектов

> VVA
Спасибо за программу

> 12345
Вариант для текстовых строк:

(defun C:Den (/ osmode a b c d e)
(if (setq a (ssget '((0 . "TEXT"))))(progn
(setq osmode (getvar "OSMODE")
      b (ssadd)
      c 0)
(setvar "CMDECHO" 0)
(command "_.undo" "_g")
(setvar "OSMODE" 0)
(repeat (sslength a)
(setq d (entget (ssname a c))
      e (cdr (assoc 10 d))
      c (1+ c))
(command "_.rectang" (mapcar '+ (cadr (Textbox d)) e ) e
     "_.rotate"(entlast) "" e (angtos (cdr (assoc 50 d)))
     "_.region" (entlast) "")
(setq b (ssadd (entlast) b))
)
(command "_.union" b "")
(setvar "OSMODE" osmode)
(command "_.undo" "_e")
(setvar "CMDECHO" 1)
))
(princ)
)

Re: LISP. Отрисовка внешнего контура выбранных объектов

> Денис Флюстиков
Так эта, спасибо конечно, но WIPEAUT вроде просит замкнутую (одну) полилинию а не область?

Re: LISP. Отрисовка внешнего контура выбранных объектов

> 12345
_boundary и ECO соответственно без разницы: облась или плиния. Задача ведь вокруг текстов отрисовать рамку, чтобы ее вместе с другими объектами скормить ECO.
Если нужны полилинии

(defun C:Den (/ osmode a b c d e)
(if (setq a (ssget '((0 . "TEXT"))))(progn
(setq osmode (getvar "OSMODE") c 0)
(setvar "CMDECHO" 0)
(command "_.undo" "_g")
(setvar "OSMODE" 0)
(repeat (sslength a)
(setq d (entget (ssname a c))
      e (cdr (assoc 10 d))
      c (1+ c))
(command "_.rectang" (mapcar '+ (cadr (Textbox d)) e ) e
   "_.rotate"(entlast) "" e (angtos (cdr (assoc 50 d)))
)
  )
(setvar "OSMODE" osmode)
(command "_.undo" "_e")
(setvar "CMDECHO" 1)
))
(princ)
)

Re: LISP. Отрисовка внешнего контура выбранных объектов

Только теперь до меня дошло. Не годится всё это, ведь требуется см.:

12345 (2007-04-05 18:06:25)

> Сергей
Не пойдет такое.
Нужен общий-групповой контур для нескольких текстовых строк и других нетекстовых примитивов, чтоб делать на основе такого контура WIPEOUT.

Т.е. 1 контур, обрисовывающий группу выбранных как тектовых, так и не текстовых примитивов.

Re: LISP. Отрисовка внешнего контура выбранных объектов

Т.е. требуется обрисовать одной замкнутой полилинией область, занимаемую группой объектов.