Работа с динамическими блоками.

;;local defuns
;;=====================================================;;
(defun getatts    (obj / attr_list)
  (setq    attr_list
     (mapcar
       (function
         (lambda (att)
           (cons (vla-get-tagstring att) (vla-get-textstring att))
           )
         )
       (vlax-invoke obj 'Getattributes)
       )
    )
  )
;;=====================================================;;
(defun getroperty  (blk / props)
  (setq    props (vlax-safearray->list
        (variant-value
          (vla-getdynamicblockproperties blk))))
  (mapcar (function (lambda (x)
              (vla-get-propertyname X)))
      props)
  )
;;=====================================================;;
(defun getvalue     (blk prop_name)
  (variant-value
    (vla-get-value
      (car
    (vl-remove-if-not
      (function (lambda (x)
              (eq prop_name (vla-get-propertyname x))))
      (vlax-safearray->list
        (variant-value
          (vla-getdynamicblockproperties blk)))))))
  )
;;==========================main part========================;;
(vl-load-com)
(defun C:test  (/ atts blkref data dps dyninfo value)
  (if
    (setq blkref (vlax-ename->vla-object
           (car (entsel "\n  >>  Выбрать блок  >>"))))
     (progn
       (if (eq :vlax-true (vla-get-hasattributes blkref))
     (progn
       (setq atts (getatts blkref))
       (princ "\nАтрибуты:")
       (princ atts)
       (princ "\n")
       )
     (princ "\nБлок не имеет атрибутов")
     )
       (if (eq :vlax-true (vla-get-isdynamicblock blkref))
     (progn
       (setq dps (getroperty blkref))
       (foreach itm     dps
         (setq value (getvalue blkref itm))
         (if (= (type value) 'SAFEARRAY)
           (setq value (vlax-safearray->list value)))
         (setq data (cons itm value))
         (setq dyninfo (cons data dyninfo)))
       (princ "\nДин. свойства:")
       (princ dyninfo)
       (princ "\n")
       )
     (princ "\nБлок не динамический")
     )
       )
     (alert "ничего не выбрано\nПовторите...")
     )
  (princ)
  )