Макрос на кнопку "Отключение слоя или группы слоев" (Страница 2 из 4)

^C^C^P(foreach item [b]'("Layer1" "Layer2" "Layer3")[/b] (if (tblobjname "layer" item) (vla-put-layeron (vla-item (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))) item) :vlax-false)));(princ);

^C^C^P(foreach item [b]'("Layer1" "Layer2" "Layer3")[/b] (if (tblobjname "layer" item) (vla-put-layeron (vla-item (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))) item) :vlax-true)));(princ);

^C^C(layer-filters-status-change "ONOFF")

  ;|=======================================================================================
* Ф-ция layer-filters-status-change
* На основе  https://www.caduser.ru/forum/topic1194.html
* Arguments [Type]:
   lstnames = String - имя группового фильтра "ONOFF"
* Возвращает [Type]:
   nil
* Если хотя бы один слой группового фильтра выключен, то слои фильтра включаются
=======================================================================================|;
(defun layer-filters-status-change
       (lstnames / vla:lrs vla:xdic vla:dic vla:spsc name datatype datavalue onoff sps)
  (setq lstnames (list lstnames))
  ;;; Utility function to get multiple group code CDRs
(defun massoc (key alist / x nlist)
  (foreach x alist
    (if (eq key (car x))(setq nlist (cons (cdr x) nlist))))
  (reverse nlist))
  (vl-load-com)
  (setq vla:lrs (vla-get-layers (vla-get-activedocument (vlax-get-acad-object))))
  (if (= (vla-get-hasextensiondictionary vla:lrs) :vlax-true)
    ;; при наличии словаря требуется детальная проверка
    (progn
      (setq lstnames (mapcar 'strcase lstnames))
      (setq vla:xdic (vla-getextensiondictionary vla:lrs))
      (setq vla:dic nil)
      ;; поиск фильтров версии 2005
      (if (progn (vlax-for item   vla:xdic
         (if (= (vla-get-name item) "ACLYDICTIONARY")
           (setq vla:dic item)
           ) ;_  if
         ) ;_  vlax-for
       vla:dic
       ) ;_  progn
   (progn
     (vlax-for vla:spsc vla:dic
       (if
         (progn
      (setq name (vla-get-name vla:spsc))
      (vla-getxrecorddata vla:spsc 'datatype 'datavalue)
      (member (strcase (vlax-variant-value
               (vlax-safearray-get-element
                 datavalue
                 (vl-position 300 (vlax-safearray->list datatype))
                 ) ;_  vlax-safearray-get-element
               ) ;_  vlax-variant-value
                  ) ;_  strcase
              lstnames
              ) ;_  member
      ) ;_  progn
          (progn
        (setq sps (entget(vlax-vla-object->ename vla:spsc))
              sps (massoc 330 (member (assoc 300 sps) sps))
              sps (vl-remove-if 'null (mapcar 'entget sps))
              sps (mapcar '(lambda (x)(cons (cdr(assoc 2 x))(cdr(assoc 62 x)))) sps))
        (if (vl-member-if '(lambda (x)(minusp (cdr x))) sps)
          (setq onoff :vlax-true) ;_Хотя бы один слой выключен
          (setq onoff :vlax-false)
          )
         (setq sps (mapcar '(lambda (x)(vla-Item vla:lrs x)) (mapcar 'car sps)))
         (mapcar '(lambda (x)(vla-put-layeron x onoff)) sps)
    
       ) ;_  progn
          ) ;_  if
       ) ;_  vlax-for
     (vlax-release-object vla:dic)
     )
   ) ;_ if
      (vlax-release-object vla:xdic)
      ) ;_  progn
    ) ;_  if
  (vlax-release-object vla:lrs)
  (princ)
  )

(layer-filters-status-change "AT")