LISP. Общее. Загрузка файла. Вызовы функций (Страница 1 из 3)

Дело в том, что при обращении к таким функциям из-под лиспа (у меня практически все такое) приходится писать не (kpblc-extlen), а (c:kpblc-extlen). И, кроме того, в передачей параметров через меню у меня что-то с c:* не срослось.

> Евгений Елпанов
По вкусу ИМХО. Мне проще сделать appload и вперед ;)
Кстати, совсем упустил из виду!
В конце файла load-apps.lsp надо добавить строку

(load-apss)

Либо, как вариант, переименовать функцию в s::startup - тогда она будет выполняться при каждой загрузке файла.

Так что, считаем, что с загрузкой и запуском все ясно, особенно новичкам, и выдаем только коды?

Однозначно - нужен! Мой подход работать может только для одноуровневых папок (т.е. никаких вложений). Код весьма интересен.

> Владимир Громов
Это хорошо, пока количество папок в support files search не превышает некий предел (то ли 12 штук, то ли 16 - не помню) - после этого кад может и не найти файлы в новых папках. А таких подпапок у меня может быть штук 20-30 (и это минимум!)
По поводу слайдов: их же можно объединять в библиотеки (у Геннадия Поспелова на сайте есть отличная программка, выполняющая эти задачи - Slide Manager называется). Исходные слайды тогда можно убирать.
поиск блоков (в качестве предложения, не проверял) - можно попробовать через (findfile) найти определенный файл, который, во-первых, прописан в путях поддержки, а, во-вторых, лежит в "корне" для блока. Например, ищем файл "blocks.def". Находим и получаем путь "c:\adds.lsp" в каталоге c:\adds.lsp\blocks лежат блоки, в каталоге c:\adds.lsp\slides - слайды. В таком случае можно написать функцию вставки блока из каталога c:\adds.lsp\blocks? указывая в качестве параметра только имя блока. Если будет время и возможность, накатаю такое (только в готовые программы кидать не буду).
Есть еще один вариант, который вообще убирает все эти проблемы. В VisualLISP IDE можно сделать проект, в котором включены все файлы (и плевать, где они физически находятся), а потом его скомпилировать в fas-файл. Но это имхо только для законченных систем.
> ZZZ : код все равно, плиз, опубликуй
---
ИМХО

> ZZZ
У меня в автозгрузке вообще ничего нет, кроме загрузки системных файлов. У меня не 20 файлов, а 200, задействованных в разных меню. Но поскольку AutoCAD'у известно с самого начала, где находятся мои файлы, то мне и достаточно написать в пункте меню или в макросе кнопки:

^C^C^P(if (null C:BI_LINE) (load "bi_line")) BI_LINE

Здесь, как вы видете, не указан путь вообще, выполняется проверка на наличие в памяти функции, и если ее нет, то загружается файл и вызывается сама функция. Да вы это все сами знаете. Я этим пользуюсь лет 10. Мне достаточно только записать соответствующий файл в соответсвующую папку и модифицировать меню, что неизбежно и - все. А в путях доступа дополнительные 5 пунктов - это мелочь, у меня бывало и 10 и все работало.

Вот, например, фрагмент меню для раздела проекта "Слаботочная сигнализация":

 [->Слабые токи]
   [Подсчет и сортировка блоков]^C^C^P(load "sp_block")
   [Подсчет и сортировка блоков на слоях CC_]^C^C^P(load "ss_block")
   [Подсчет суммарной длины кабелей]^C^C^P(load "sp_kbl")
   [Трассировка линий связи]^C^C^P(load "trassa")
   [--]
   [->Блоки]
   [Палатная сигнализация]^C^C^P(if (not C:ПАЛАТА) (load "ddpalata")) ПАЛАТА
   [Сети Радио]^C^C^P(if (not C:РАДИО) (load "ddradio")) РАДИО
   [Часы]^C^C^P(if (not C:ЧАСЫ) (load "ddclock")) ЧАСЫ
   [Телефонная сеть]^C^C^P(if (not C:ТЕЛЕФОН) (load "ddtelefon")) ТЕЛЕФОН
   [Пожарная сигнализация]^C^C^P(if (not C:ПОЖАР) (load "ddpogar")) ПОЖАР
   [Охранная сигнализация]^C^C^P(if (not C:ОХРАНА) (load "ddohrana")) ОХРАНА
   [Контроль доступа]^C^C^P(if (not C:КОНТРОЛЬ) (load "ddkontrol")) КОНТРОЛЬ
   [Сети ТВ]^C^C^P(if (not C:ТВ) (load "ddtv")) ТВ
   [<-<-Локальные сети]^C^C^P(if (not C:ЛВС) (load "ddlvs")) ЛВС

Там, где записана только "load...", функция определена через (apply '(lambda ()...
Никаких путей и меню одинаковое у всех.

Я, начинающий юзер. Начинаю работать с LISP; VBA приложениями.
Ничего не понял. Что за команды? Что за "соответствующие папки"?
В Windows XP куда- то все проваливается. Хрен найдешь. Иконки рисую каждый раз как начинаю работать:(  Или Владимир пишет: "Никаких путей и меню одинаковое у всех.". Что это?

Ок. самый простой - складывать все файлы в одну папку и делать как Вы описываете.
---
ИМХО

Если читаете книгу "САПР на базе AutoCAD...", то внимательнее. Там все расписано.
Функции типа (C:XXX) имитируют команды Автокада. Чтобы бестолковые буржуи могли набрать в командной строке. Плюс повтор нажатием Enter.
Но в такие функции нельзя передавать параметры. И это их главный недостаток. Но никто же не заставляет так писать. Пишите обычные функции, передавайте в них аргументы и используйте одну функцию для тысяч "команд", привязанных к меню.
Называть свои "команды" ТЕЛЕФОН, ОХРАНА и т.п. можно, пока их немного. А как только начнете делать программы для пяти сотен "электрических" рисунков, то и слов не хватит, и запомнить их будет невозможно. Все равно программа будет привязываться к меню или кнопке. А значит и ее осмысленное имя значения не имеет, не надо использовать префикс C:, и все команды можно заменить на одну единственную.
Проверка типа (if (not C:ТЕЛЕФОН) (load "ddtelefon")) дает сомнительную экономию на сотых долях секунды загрузки. Зато, если вы отрабатываете программу, и она изменена, то ее придется загружать заново как-то вручную.
Вообще надо разделять свои ЛИСПы на библиотеки функций, которые загружаются один раз, и на прикладные программы, максимально использующие библиотеки. Прикладные программы - загружать из меню. И не заставлять пользователя что-то набирать после загрузки. Программа должна загрузиться и сама запуститься.
Конструкция
(mapcar 'load
(z-files-in-directory (strcat *z_root_dir* "Lisp") "*.lsp" t)
)
может и не применяться. Лучше сделать проект своей библиотеки в Visual Lisp и компилировать кучу своих LSP в один FAS. Это удобнее и компилированные работают намного быстрее.

Подниму-ка по новой тему ;) Учитывая предложения, получаем:

;|=======================================================================================
*    Выполняет загрузку всех файлов системы. За компанию создает ссылку на активный
* документ.
*    Поскольку основная область работы - ACAD LT + LT Extender, применение fas-файлов
* невозможно (ограничение LT Extender)
*    Дополнительно: файл сохранить как kpblc-loader.lsp и прописать его в автозагрузку.
*    Возможно применение иных имен, надо будет заменить строки
    filename          (findfile "kpblc-loader.lsp")
<...>
    (if (/= (vl-filename-base file_counter) "kpblc-loader")
на Ваше имя автозагрузчика
Также заменить слово "kpblc" на более привычное Вам.
=======================================================================================|;
(defun kpblc-loader( / files_list filename)
  (vl-load-com)
  (setq *kpblc-activedoc*   (vla-get-activedocument (vlax-get-acad-object))
    *kpblc-acad-object* (vlax-get-acad-object)
    *kpblc-model*       (vla-get-modelspace *kpblc-activedoc*)
    *kpblc-layout*      (vla-get-layouts    *kpblc-activedoc*)
    filename          (findfile "kpblc-loader.lsp")
    files_list (z-files-in-directory
             (vl-filename-directory filename)
             "*.lsp"
             T)
    );_setq
  ;;(mapcar 'load files_list)
  (foreach file_counter files_list
    (if (/= (vl-filename-base file_counter) "kpblc-loader")
      (load file_counter)
      );_if
    )
  )
;|=======================================================================================
*    функция z-files-in-directory возвращает список файлов находящаяся в заданной
* директории
*    Автор : ZZZ
*    Источник : https://www.caduser.ru/forum/topic19699.html
*
*    Параметры:
*        directory    путь к папке например "D:\\Мои документы\\ZEF\\Lisp"
*        pattern        шаблон например "*.lsp"
*        nested        искать в вложенных папках: t (да) или nil (нет)
* Пример вызова:
(z-files-in-directory "D:\\Мои документы\\ZEF\\Lisp" t)
(z-files-in-directory (vl-directory-files (strcat (vl-filename-directory (findfile "kpblc-loader.lsp")))) "*.lsp" T)
=======================================================================================|;
(defun z-files-in-directory (directory pattern nested /)
  (if nested
    (apply 'append
       (append (list (mapcar '(lambda (f) (strcat directory "\\" f))
                 (vl-directory-files directory pattern 1)
                 ) ;_ mapcar
             ) ;_ list
           (mapcar '(lambda (d)
                  (z-files-in-directory
                (strcat directory "\\" d)
                pattern
                nested
                ) ;_ z-files-in-directory
                  ) ;_ lambda
               (cddr (vl-directory-files directory nil -1))
               ) ;_ mapcar
           ) ;_ append
       ) ;_ append
    (mapcar '(lambda (f) (strcat directory "\\" f))
        (vl-directory-files directory pattern 1)
              ) ;_ mapcar
    ) ;_ if
  ) ;_ defun
(kpblc-loader)

Прошу ногами не бить - прога работает, бОльшего от нее (пока?) не требуется.