Тема: LISP. Для генпланистов: построение линии с уклоном
Даная функция строит линию с заданным в промиллях вертикальным! уклоном. Заданый уклон сохраняется в глобальной переменной *RUNA_DDLSLOPE*, если задаете уклон с + то следущая точка будет выше предыдущей. Линия будет трехмерной.
;;;Построение линии по начальной точке и уклону заданому в промилях
(defun c:ddl (/ END_ELEV END_POINT SLOPE ST_ELEV ST_POINT)
;|
; Global variables: (*RUNA_DDLSLOPE*)
|;
(if (not *runa_ddlslope*) (setq *runa_ddlslope* 5))
(setq slope (GETREAL
(STRCAT "Specify slope in promille or <"
(rtos *runa_ddlslope* 2) " ?>: ")))
(if (null slope)
(setq slope *runa_ddlslope*)
(setq *runa_ddlslope* slope))
(setq st_point (getpoint "DDL Specify first point: "))
(if (null st_point)
(setq st_point (GETVAR "LASTPOINT")))
(setq st_elev (last st_point))
(setq st_elev (GETREAL
(STRCAT "\nStart elevation <"
(rtos st_elev 2) ">: ")))
(if (null st_elev)
(setq st_elev (last st_point)))
(setq end_point (getpoint st_point "Specify end point of line: "))
(if (null end_point)
(princ "Cannot build a zero length line.")
(progn
(setq end_elev
(+ st_elev
(* slope 0.001
(setq dist_in_plane
(distance
(cdr (reverse st_point))
(cdr (reverse end_point)))))))
(command "_.line"
".xy"
"none"
st_point
st_elev
".xy"
"none"
end_point
end_elev
"")
(princ (STRCAT "\nEnd elevation: "
(rtos end_elev 2)
" Distance in plane: "
(rtos dist_in_plane 2)))
);progn
);if
(princ)
); end defunА вот и функция для подсчета уклонов и расстояний на генплане:
Возвращает в командную строку типа:
Distance = 4.6924 , Slope = 0.000 ?, Delta Z = 0.0000 . Dist by z: 4.6924 , L(M 1:500)= 9.3848 , L(M 1:200)= 23.4619
Где Distance = 4.6924 - расстояние в плане
Slope = 0.000 ? - уклон в промиллях если с + то вторая точка была выше
Delta Z = 0.0000 превышение
Dist by z: 4.6924 расстояние с учетом Z - координат
L(M 1:500)= 9.3848 - расстояние в мм в 500 масштабе
L(M 1:200)= 23.4619 - тоже но для 200.
только не пугайтесь:)
(defun c:rdd ( / runa01 runa02 runa03 runa04 runa05)
(setq runa01 (GETPOINT "\nSpecify first point: "))
(if (null runa01) (setq runa01 (getvar "LASTPOINT")))
(setq runa02 (GETPOINT runa01 " Specify second point: "))
(if (null runa02) (princ "\nCannot computer distance.")
(PROGN
(setq runa03 (- (last runa02) (last runa01))
runa05 (distance runa01 runa02))
(setq runa01 (list (car runa01) (cadr runa01))
runa02 (list (car runa02) (cadr runa02)))
(setq runa04 (distance runa01 runa02))
(princ (STRCAT "\nDistance = " (RTOS runa04 2)
" м, Slope = "
(rtos (* (/ runa03 runa04) 1000) 2 3)
" ?, Delta Z = " (rtos runa03 2) " м."))
(princ (STRCAT "\nDist by z: "
(rtos runa05 2) " м, L(M 1:500)= "
(rtos (/ runa04 0.5) 2) " мм, "
"L(M 1:200)= " (rtos (/ runa04 0.2) 2) " мм"))
);PROGN
);if
(princ)
);end defunИмена команд DDL RDD
Макросы
^C^CDDL
'RDD - может работать в прозрачном режиме (точнее как лисп-выражение)
