Как создать свою клавишу меню?

> Владимир Громов
Пока получилось только это: ^C^C_move \50\
Направление задаётся также, как и при простом перемещении, но подтверждается перемещение правой кнопкой мыши, а не левой:(. И не знаю, куда положить пиктограмму, но это сам найду:). Спасибо.

Как вариант:

(defun C:MOVE50 ( / osm obj pp1 pp2 pp3)
(setq osm (getvar "OSMODE"))
(setvar "OSMODE" 0)
(setq obj (entsel "\n Выберите объект (можно с объектной привязкой): "))
(setq pp1 (nth 1 obj))
(setq pp2 (getpoint pp1 "\n Укажите точку направления перемещения: "))
(vl-cmdf "_UCS" "_3" pp1 pp2 "")
(setq pp3 (list (+ (car pp1) 50) (cadr pp1)))
(vl-cmdf "_MOVE" obj "" pp1  pp3)
(vl-cmdf "_UCS" "_WORLD")
(setvar "OSMODE" osm)
(princ)
)

Код сохранить в файле move50.lsp на пути доступа AutoCAD'а к файлам поддержки.
Возможный макрос для кнопки или пункта меню:

^C^C(if (not C:MOVE50) (load "move50")) MOVE50

> Владимир Громов
кстати, и все привязки выключаются:(.

> lloyd
А разве при предварительном выборе не надо попасть точно в объект? Привязки я убрал для того, чтобы объект выбирался с помощью прицела выбора объектов и только в необходимом случае - с помощью объектных привязок, которые можно выбрать в контекстном меню или в панели привязок. В данном случае применение функции (entcel) позволяет не указывать базовую точку, она определяется при выборе объекта, но, к сожалению (в данном случае), позволяет выбрать только один объект. Я думаю, что усложнив код, можно сделать и множественный выбор объектов. По поводу предварительного выбора объектов. Я вот, например, предпочитаю сначала определиться с тем, какую команду я хочу выполнить, а уж потом - какие объекты выбрать для этой команды. Но это не догма, можно предусмотреть и возможность предварительного выбора. Мне самому мой вариант программы с изенением ПСК не очень нравится, делал первое, что в голову пришло. У Александра Ривилиса, естественно, получилось лучше, только я не совсем понимаю, почему понадобилось для (if) задавать одновременно три условия.

> Александр Ривилис
Я это сообразил, пока отправлял сообщение, но подумал - пусть Александр Ривилис, все-таки, объяснит.
Чуть-чуть добавил в код:

(defun C:MOVE50 ( / osm obj pp1 pp2 pp3)
 (if (and (setq obj (entsel "\n Выберите объект: "))
          (setq pp1 (cadr obj) obj (car obj))
          (setq pp2 (getpoint pp1 "\n Укажите точку направления перемещения: ")))
  (progn
    (setq pp3 (polar pp1 (angle pp1 pp2) 50))
    (setq osm (getvar "OSMODE"))
    (setvar "OSMODE" 0)
    (vl-cmdf "_.MOVE" obj "" pp1  pp3)
    (setvar "OSMODE" osm)
  )
  (princ "\n Объект не выбран или отказ.")
 )
 (princ)
)