Защита от редактирования !!! (Страница 2 из 3)

;Restore line from %%U text
;Text to Line
(defun C:T2L ( / txt_to_line mip:layer-status-restore mip:layer-status-save *error*)
(defun *error* (msg)(princ msg)(mip:layer-status-restore)(princ))
(defun mip:layer-status-restore ()
    (foreach item *MIP_LAYER_LST*
      (if (not (vlax-erased-p (car item)))
        (vl-catch-all-apply
          '(lambda ()
             (vla-put-lock (car item) (cdr (assoc "lock" (cdr item))))
             (vla-put-freeze (car item) (cdr (assoc "freeze" (cdr item))))
             ) ;_ end of lambda
          ) ;_ end of vl-catch-all-apply
        ) ;_ end of if
      ) ;_ end of foreach
    (setq *MIP_LAYER_LST* nil)
    ) ;_ end of defun
  (defun mip:layer-status-save ()
    (setq *MIP_LAYER_LST* nil)
    (vlax-for item (vla-get-layers *kpblc-activedoc*)
      (setq *MIP_LAYER_LST* (cons (list item
                                  (cons "freeze" (vla-get-freeze item))
                                  (cons "lock" (vla-get-lock item))
                                  ) ;_ end of cons
                            *MIP_LAYER_LST*
                            ) ;_ end of cons
            ) ;_ end of setq
      (vla-put-lock item :vlax-false)
      (vl-catch-all-apply '(lambda () (vla-put-freeze item :vlax-false)))
      ) ;_ end of vlax-for
    ) ;_ end of defun
(defun txt_to_line (/ krivoy_text)
  (if
    (and
      (setq krivoy_text (ssget '((0 . "TEXT") (1 . "%%U "))))
      (setq krivoy_text
       (vl-remove-if
         'listp
         (mapcar
     'cadr
     (ssnamex krivoy_text)
         )
       )
      )
    )
     (mapcar '(lambda (x / ent newline box endpt col)
    (setq
      ent    (entget x)
      box    (textbox ent)
      )
   (setq
      newline (vla-addline
          (vla-get-ModelSpace
            (vla-get-ActiveDocument (vlax-get-acad-object))
          )
          (vlax-3d-point
            (setq
        endpt (mapcar '+
                (cdr (assoc 10 ent))
                (cond
            (
             (= (cdr (assoc 71 ent)) 0)
             (car box)
            )
            (t
             (list (caar box)
                   (cadr (cadr box))
                   0.0
             )
            )
                )
              )
            )
          )
          (vlax-3d-point (polar endpt 0 (caadr box)))
        )
    )
    (vla-rotate
      newline
      (vlax-3d-point (cdr (assoc 10 ent)))
      (cdr (assoc 50 ent))
    )
    (vla-put-layer newline (cdr (assoc 8 ent)))
    (vla-put-Color newline
      (if (setq col (cdr (assoc 62 ent))) col 256))
    (entdel x)
        )
       krivoy_text
     )
  )
  (princ)
)
  (vl-load-com)
(mip:layer-status-save)
  (princ "\nSelect text")
  (txt_to_line)
(mip:layer-status-restore)
(princ "\nGood work with line ...")
(princ)
  )