Как удалить или слить стили текста

(defun c:setstyle (/                 *error*           adoc
                   loc:restore-layers                  lst:layers
                   style             _kpblc-conv-vla-to-list
                   lst:attr
                   )
  (defun *error* (msg)
    (loc:restore-layers)
    (vla-endundomark adoc)
    (princ msg)
    (princ)
    ) ;_ end of defun
  (defun _kpblc-conv-vla-to-list (value / res)
                                 ;|
*    Преобразовывает vlax-variant или vlax-safearray в список.
|;
    (cond
      ((listp value)
       (mapcar '_kpblc-conv-vla-to-list value)
       )
      ((= (type value) 'variant)
       (_kpblc-conv-vla-to-list (vlax-variant-value value))
       )
      ((= (type value) 'safearray)
       (if (>= (vlax-safearray-get-u-bound value 1) 0)
         (_kpblc-conv-vla-to-list (vlax-safearray->list value))
         ) ;_ end of if
       )
      (t value)
      ) ;_ end of cond
    ) ;_ end of defun
  (defun loc:restore-layers ()
    (foreach item lst:layers
      (vla-put-lock (car item) (cdr (assoc "lock" (cdr item))))
      (vl-catch-all-apply
        '(lambda ()
           (vla-put-freeze (car item) (cdr (assoc "freeze" (cdr item))))
           ) ;_ end of lambda
        ) ;_ end of vl-catch-all-apply
      ) ;_ end of foreach
    ) ;_ end of defun
  (vl-load-com)
  (vla-startundomark
    (setq adoc (vla-get-activedocument (vlax-get-acad-object)))
    ) ;_ end of vla-startundomark
  (vlax-for item (vla-get-layers adoc)
    (setq lst:layers
           (cons (list item
                       (cons "lock" (vla-get-lock item))
                       (cons "freeze" (vla-get-freeze item))
                       ) ;_ end of list
                 lst:layers
                 ) ;_ end of cons
          ) ;_ end of setq
    (vla-put-lock item :vlax-false)
    (vl-catch-all-apply '(lambda () (vla-put-freeze item :vlax-false)))
    ) ;_ end of vlax-for
  (setq style (vla-get-name (vla-get-activetextstyle adoc)))
  (vlax-for blk_def (vla-get-blocks adoc)
    (if (equal (vla-get-isxref blk_def) :vlax-false)
      (vlax-for ent blk_def
        (cond
          ((wcmatch (strcase (vla-get-objectname ent)) "*TEXT,*DIMEN*")
           (vl-catch-all-apply '(lambda () (vla-put-textstyle ent style)))
           )
          ((and
             (= (vla-get-objectname ent) "AcDbBlockReference")
             (setq lst:attr (apply
                              'append
                              (mapcar
                                '_kpblc-conv-vla-to-list
                                (list (vla-getattributes ent)
                                      (vla-getconstantattributes ent)
                                      ) ;_ end of list
                                ) ;_ end of mapcar
                              ) ;_ end of apply
                   ) ;_ end of setq
             ) ;_ end of and
           (foreach item lst:attr
             (vl-catch-all-apply '(lambda () (vla-put-textstyle item style)))
             ) ;_ end of foreach
           )
          ) ;_ end of cond
        ) ;_ end of vlax-for
      ) ;_ end of if
    ) ;_ end of vlax-for
  (vla-regen adoc acallviewports)
  (vla-endundomark adoc)
  (princ)
  ) ;_ end of defun