Новая вкладка меню с макросом

Sub Example_AddSubMenu()
    ' This example creates a new menu called TestMenu and ins erts a submenu item
    ' called NewFile. It then creates a menu item, called open,
    ' on the submenu.
    
    ' The menu is then displayed on the menu bar.
    ' To remove the menu after execution of this macro, use the Customize Menu
    ' option from the Tools menu.
    
    Dim currMenuGroup As acadMenuGroup
    Set currMenuGroup = ThisDrawing.Application.MenuGroups.Item(0)
    
    ' Create the new menu
    Dim newMenu As AcadPopupMenu
    Set newMenu = currMenuGroup.Menus.Add("TestMenu")
    
    ' Add the submenu
    Dim FileSubMenu As AcadPopupMenu
    Set FileSubMenu = newMenu.AddSubMenu("", "NewFile")
    
    
    ' Add a menu item to the sub menu
    Dim newMenuItem As AcadPopupMenuItem
    Dim openMacro As String
    
    ' Assign the macro string the VB equivalent of "ESC ESC _open "
    openMacro = Chr(3) & Chr(3) & Chr(95) & "open" & Chr(32)
    
    Set newMenuItem = FileSubMenu.AddMenuItem(newMenu.count + 1, "Open", openMacro)
    
    ' Display the menu on the menu bar
    newMenu.InsertInMenuBar (ThisDrawing.Application.MenuBar.count + 1)
    
End Sub

'ФУНКЦИЯ ПРОВЕРКИ, ЗАГРУЖЕНА ЛИ ОПРЕДЕЛЕННАЯ ГРУППА МЕНЮ
Private Function MenuGroupExist(MenuName As String) As Boolean
Dim MenuGroup As AcadMenuGroup
MenuGroupExist = False
MenuName = UCase(MenuName)
For Each MenuGroup In Application.MenuGroups
    If MenuGroup.Name = MenuName Then
        MenuGroupExist = True
        Exit Function
    End If
Next
End Function

'ФУНКЦИЯ ЗАГРУЗКИ ГРУППЫ МЕНЮ
Private Function AddMenuGroup(MenuName As String, MenuFileName As String) As Long
'MenuName - имя группы меню
'MenuFileName - полный путь файла группы меню (.cui файл)
'Результат:
'AddMenuGroup = -1 - не удалось загрузить файл частичной адаптации
'AddMenuGroup =  0 - файл частичной адаптации уже загружен
'AddMenuGroup =  1 - удачная загрузка файла частичной адаптации

Dim MenuGroupObject As AcadMenuGroup
If MenuGroupExist(MenuName) Then
    AddMenuGroup = 0
Else
    On Error Resume Next
    Set MenuGroupObject = Application.MenuGroups.Load(MenuFileName, False)
    If Err.Number = 0 Then AddMenuGroup = 1 Else AddMenuGroup = -1
    On Error GoTo 0
End If
End Function

'ФУНКЦИЯ ВЫГРУЗКИ ГРУППЫ МЕНЮ
Private Function DelMenuGroup(MenuName As String) As Long
'MenuName - имя группы меню
'Результат:
'DelMenuGroup = -1 - не удалось выгрузить файл частичной адаптации
'DelMenuGroup =  0 - файл частичной адаптации незагружен
'DelMenuGroup =  1 - удачная выгрузка файла частичной адаптации
Dim MenuGroupObject As AcadMenuGroup
If MenuGroupExist(MenuName) Then
    On Error Resume Next
    Application.MenuGroups.Item(MenuName).Unload
    If Err.Number <> 0 Then
        DelMenuGroup = -1
        Exit Function
    End If
    On Error GoTo 0
    DelMenuGroup = 1
Else
    DelMenuGroup = 0
End If
End Function