Измерения в Инвенторе

 Private WithEvents oInteraction As InteractionEvents = Nothing
    Private WithEvents omouseEvent As MouseEvents = Nothing
    Private opDoc As ComponentOccurrence = Nothing
    Private oTransform As Matrix
    '===========================================
    ' Действие при нажатии кнопки
    Private Sub ToolStripButton7_Click(ByVal sender As System.Object, _
                 ByVal e As System.EventArgs) Handles ToolStripButton7.Click
        If m_inventorApplication.ActiveDocumentType <> DocumentTypeEnum.kAssemblyDocumentObject Then Exit Sub
        Dim ocmdMgr As CommandManager
        Try
            If Not m_inventorApplication.ActiveView Is Nothing Then
                'Вставляем модель C:\\Part1.ipt (можно запросить у пользователя) в начало координат
                Dim oADoc As AssemblyDocument
                oADoc = m_inventorApplication.ActiveDocument

                Dim oAsmCompDef As AssemblyComponentDefinition
                oAsmCompDef = oADoc.ComponentDefinition

                Dim oTG As TransientGeometry
                oTG = m_inventorApplication.TransientGeometry
                oTransform = oTG.CreateMatrix
                opDoc = oAsmCompDef.Occurrences.Add("C:\\Part1.ipt", oTransform)

                'Включаем отслежевание курсора мыши
                ocmdMgr = m_inventorApplication.CommandManager
                oInteraction = ocmdMgr.CreateInteractionEvents()
                omouseEvent = oInteraction.MouseEvents
                omouseEvent.MouseMoveEnabled = True
                oInteraction.Start()
            End If
        Catch ex As Exception
        End Try
    End Sub
    Private Sub omouseEvent_OnMouseClick(ByVal Button As Inventor.MouseButtonEnum, ByVal ShiftKeys As Inventor.ShiftStateEnum, ByVal ModelPosition As Inventor.Point, ByVal ViewPosition As Inventor.Point2d, ByVal View As Inventor.View) Handles omouseEvent.OnMouseClick
        'Отключаем отслежевание курсора мыши, фиксируя вставку модели
        If Not oInteraction Is Nothing Then
            oInteraction.Stop()
            omouseEvent = Nothing
            oInteraction = Nothing
            opDoc = Nothing
        End If
    End Sub
    Private Sub omouseEvent_OnMouseMove(ByVal Button As Inventor.MouseButtonEnum, ByVal ShiftKeys As Inventor.ShiftStateEnum, ByVal ModelPosition As Inventor.Point, ByVal ViewPosition As Inventor.Point2d, ByVal View As Inventor.View) Handles omouseEvent.OnMouseMove
        'Перемещаем модель за курсором мыши. Если ошибка, отключаем отслежевание, удаляем модель
        Try
            oTransform.SetTranslation(m_inventorApplication.TransientGeometry.CreateVector(ModelPosition.X, ModelPosition.Y, ModelPosition.Z))
            opDoc.Transformation = oTransform
            View.Update()
        Catch ex As Exception
            If Not oInteraction Is Nothing Then
                oInteraction.Stop()
                omouseEvent = Nothing
                oInteraction = Nothing
                opDoc.Delete()
                opDoc = Nothing

            End If
        End Try
    End Sub