Программа+макрос на кнопку "Ориентирование обьектов в AutoCAD по контрольной линии" (Страница 1 из 3)

Опять - двадцать пять. Приходится догадываться, что именно хочет т. Forma. А хочет он, видимо, выровнять криво отсканированный и вставленный в DWG растр, IMHO. Если это так, то тут как раз и пригодится команда "_ALIGN" ("ВЫРОВНЯТЬ"). Только автоматизировать там нечего, все и так просто. Если я не угадал, то считайте меня коммунистом.

> Forma
Вот какая ситуация бывает у меня. Имеется сканированный план здания, иногда склеенный из кусков, т.к. мне доступен только сканер формата А3, а чертежи бывают формата > А1. Ясно, что растр не получится ортогональным, хоть ты тресни. Тогда я провожу из одного угла этого растра вертикальную или горизонтальную линию и выравниваю растр по одной паре точек. Это получается достаточно быстро и автоматизации не требует. Если же хочется иметь сознательно повернутый растр, то лучше его заранее обработать в редакторе растровых изображений и лучшим из них я считаю Ulead PhotoImpact.

Вот, посмотри здесь:
http://www.upi.kiev.ua/
Сам я глянул только мельком.

> Forma
Оно?

(defun C:ALIGN_IMAGE ( / ss en el p1 p2 u v ang tmp i n ul vl)
  (defun vector_len (v / x y z)
    (setq x (nth 0 v) y (nth 1 v) z (nth 2 v))
    (sqrt (+ (* x x) (* y y) (* z z)))
  )
  (princ "\nВыберите отрезок, по которому будет выполняться выравнивание: ")
  (if (setq ss (ssget "_:S:E" '((0 . "LINE")))) (progn
    (setq el (entget (ssname ss 0)))
    (setq p1 (cdr (assoc 10 el)) p2 (cdr (assoc 11 el)))
    ;; Упорядочим отрезок по оси X
    (if (> (car p1) (car p2)) (progn
      (setq tmp (list p1 p2) p1 (last tmp) p2 (car tmp))
    )) ;; (if (progn
    (setq ang (angle p1 p2))
    (princ "\nВыберите растры для выравнивания: ")
    (if (setq ss (ssget '((0 . "IMAGE")))) (progn
      (setq n (sslength ss) i 0)
      (while (< i n)
        (setq el (entget (ssname ss i)))
        (setq u (cdr (assoc 11 el)) v (cdr (assoc 12 el)))
        (setq el (subst (cons 11 (polar '(0.0 0.0 0.0)
                 ang (vector_len u))) (assoc 11 el) el))
        (setq el (subst (cons 12 (polar '(0.0 0.0 0.0)
                 (+ ang (* PI 0.5)) (vector_len v))) (assoc 12 el) el))
        (entmod el)
        (setq i (1+ i))
      )
    )) ;; (if (progn
  )) ;; (if (progn
  (princ)
)

> Forma
Надеюсь, что все нормально. Программа обрабатывает только растры (для других типов объектов нужны свои алгоритмы - единообразия достичь вряд ли получится).

> Александр Ривилис
Вспомнил. Днем вертелся вопрос в голове. Точность поворота какая заложена? Нужно не менее 15 минут. Может там по умолчанию округление до целых градусов.

> Forma
Что имеется в виду под словом "репер"?

> Forma

> Владимир Громов
Вы оба меня озадачили. Ну по поводу отмены команды - тут и так все ясно, а вот по поводу выравнивания по вертикальному отрезку... И как же интересно я буду догадываться нужно ли мне выравнивать низ растра или бок? А если отрезок наклонный? Нет уж увольте... Выравнивается всегда низ растра. Угол измеряется с той точностью, с которой позволяет AutoCAD и нигде не округляется, если не учитывать потери при вычислениях.

> Александр Ривилис
Хоть я лицо и не вполне заинтересованное, но хочу уточнить. Сразу оговорюсь, что мое замечание ни к чему не обязывает. А дело вот в чем. У меня бывают старые чертежи, выполненные на доске и в них не всегда выдержан угол 90 градусов между горизонтальными и вертикальными линиями. Поэтому при обводке растра в AutoCAD'е приходится решать: если превалируют вертикальные линии, то и выравнивать надо по вертикали, а уж горизонтальные как получатся в режиме ОРТО. Задача ведь состоит не просто в выравнивании рамки растра, а того, что в нем нарисовано. Вот и все с моей стороны.

Меня программа вполне устраивает. Но, как- бы незавершенная.
В LISP есть операторы подобные  "if";"else";"goto" т.п.? Это я к тому, что- бы
отсортировать два "признака" контрольной линии: близкой к горизонтали (0-45;315-360) и близкой к вертикали (45-135;225-315).
С учетом, есс-но, >=.
По первому признаку повернуть горизонтальную составляющую растра, по второму- по вертикальной.
А, то я вроде как неформально ответственный за эту ветку на форуме.:)))

> Forma
Где-то так:

(defun C:ALIGN_IMAGE ( / ss en el p1 p2 u v ang tmp i n ul vl)
  (defun vector_len (v / x y z)
    (setq x (nth 0 v) y (nth 1 v) z (nth 2 v))
    (sqrt (+ (* x x) (* y y) (* z z)))
  )
  (princ "\nВыберите отрезок, по которому будет выполняться выравнивание: ")
  (if (setq ss (ssget "_:S:E" '((0 . "LINE")))) (progn
    (setq el (entget (ssname ss 0)))
    (setq p1 (cdr (assoc 10 el)) p2 (cdr (assoc 11 el)))
    ;; Упорядочим отрезок по оси X
    (if (> (car p1) (car p2)) (progn
      (setq tmp (list p1 p2) p1 (last tmp) p2 (car tmp))
    )) ;; (if (progn
    (setq ang (angle p1 p2))
    ;; Разберемся с углом:
    (cond
     ((and (> ang (* PI 0.25)) (< ang (* PI 0.75)))
      (setq ang (- ang (* PI 0.5)))
     )
     ((and (> ang (* PI 1.25)) (< ang (* PI 1.75)))
      (setq ang (+ ang (* PI 0.5)))
     )
    ) ;; (cond
    (princ "\nВыберите растр для выравнивания: ")
    (if (setq ss (ssget "_:S:E" '((0 . "IMAGE")))) (progn
      (setq n (sslength ss) i 0)
      (while (< i n)
        (setq el (entget (ssname ss i)))
        (setq u (cdr (assoc 11 el)) v (cdr (assoc 12 el)))
        (setq el (subst (cons 11 (polar '(0.0 0.0 0.0)
                 ang (vector_len u))) (assoc 11 el) el))
        (setq el (subst (cons 12 (polar '(0.0 0.0 0.0)
                 (+ ang (* PI 0.5)) (vector_len v))) (assoc 12 el) el))
        (entmod el)
        (setq i (1+ i))
      )
    )) ;; (if (progn
  )) ;; (if (progn
  (princ)
)

> Forma
Посыпаю голову пеплом. Неправильно поставил задачу. Уважаемый Александр Ривилис выполнил в точности, что я просил.:(
А, не менее уважаемый Владимир Громов деликатно подсказывал мне, что я пру как баран не в ту сторону.
Вот к чему приводят методы пригодные только для ловли блох.
Короче, надо привести кривой растр к ORTO по построеной контрольной линии. Есть у меня предчувствие, что все дело в знаках + и -.  Не смею просить. Только надеюсь и уповаю.